{curl 4.0, 5.0, 6.0, 7.0 applet}
{import * from CURL.DOC.CONTENT.ACCESSORIES}
{document-style PlainDocument}
{value
    def query = {get-base-url}.query
    let title:String = ""
    let contents:StringInterface = ""
    {if {query.prefix? "?"} then
        {for part in {query.split split-chars = "?&"} do
            def i = {part.find '='}
            {if i > 0 then
                def name = {part.substr 0, i}
                def value = {part.substr i + 1, part.size - i - 1}
                {switch name
                 case "title" do
                    set title = {url-decode-string value}
                 case "url" do
                    {try
                        def u = {url {url-decode-filename value}}
                        set contents = {read-from u}
                     catch ex:Exception do
                        set contents =
                            {format
                                {stringify
                                    {text color = "red", Could not read example:
                                        %w
                                    }
                                },
                                ex.message
                            }
                    }
                 case "content" do
                    set contents = {url-decode-string value}
                }
            }
        }
    }
    {evaluate
        {format
            {stringify
                {example title = %w, %s}
            },
            title,
            contents
        }
    }
}